package index{
 
 
	import flash.events.Event;
	import flash.events.MouseEvent;
	import org.papervision3d.cameras.Camera3D;
	import org.papervision3d.core.geom.renderables.Vertex3D;
	import org.papervision3d.core.math.Plane3D;
	import org.papervision3d.core.math.Number3D;
	import org.papervision3d.core.utils.InteractiveUtils;
	import org.papervision3d.core.utils.Mouse3D;
	import org.papervision3d.events.InteractiveScene3DEvent;
	import org.papervision3d.lights.PointLight3D;
	import org.papervision3d.materials.shadematerials.GouraudMaterial;
	import org.papervision3d.materials.WireframeMaterial;
	import org.papervision3d.objects.primitives.Sphere;
	import org.papervision3d.objects.primitives.Plane;
	import org.papervision3d.render.QuadrantRenderEngine;
	import org.papervision3d.view.BasicView;
 
 
 
	public class World extends BasicView{
 
 
		public function World(viewportWidth:Number=640, viewportHeight:Number=480, scaleToStage:Boolean=true, interactive:Boolean=false, cameraType:String="TARGET"){
			super(viewportWidth, viewportHeight, scaleToStage, interactive, cameraType);
 
			//マウス3Dを有効
			Mouse3D.enabled	= true;
 
			//ライト
			this.light	= new PointLight3D();
			this.light.y= 1000;
 
			//XZ無限平面
			this.plane3d = new Plane3D( new Number3D( 0, 1, 0 ), new Number3D( 0, 0, 0 ) );
 
 
			//地面
			this.plane	= new Plane( new WireframeMaterial(0x0000ff,0.5), 10000,10000,10,10);
			this.plane.rotationX = 90;
 
			//球
			this.sphere	= new Sphere( new GouraudMaterial( this.light, 0xffffff, 0x00ff00, 200 ), 100, 20, 20 );
			this.sphere.material.interactive = true;
			this.sphere.y = 100;
 
			//レンダラ
			this.renderer	= new QuadrantRenderEngine();
 
			//カメラ
			this.camera.z		= -1500;
			this.camera.orbit( -45, _yaw );
 
 
			this.scene.addChild( this.plane );
			this.scene.addChild( this.sphere );
 
			this.startRendering();
 
			this.addEventListener( Event.ADDED_TO_STAGE, this.addedToStageHandler, false, 0, true );
		}
 
 
 
		public var light:PointLight3D;
		public var plane3d:Plane3D;
		public var plane:Plane;
		public var sphere:Sphere;
		public var subNum:Number3D;
		public var _yaw:Number = 90;
 
 
 
		public function addedToStageHandler(e:Event):void{
			this.sphere.addEventListener( InteractiveScene3DEvent.OBJECT_PRESS, this.objectPressHandler, false, 0, true );
			this.stage.addEventListener( MouseEvent.MOUSE_UP, this.mouseUpHandler, false, 0, true );
			this.stage.addEventListener( MouseEvent.MOUSE_WHEEL, this.mouseWheelHandler, false, 0, true );
		}
 
 
 
 
		public function objectPressHandler(e:InteractiveScene3DEvent):void{
			//マウスプレスした位置のワールド座標
			var mouseNum:Number3D = viewport.interactiveSceneManager.mouse3D.position;
			//オブジェクト中心との差
			subNum = Number3D.sub( mouseNum, e.displayObject3D.position );
			//無限平面をオブジェクトのy座標に移動
			plane3d.setNormalAndPoint( new Number3D( 0, 1, 0 ), new Number3D( 0, -mouseNum.y, 0 ) );
 
			//マウス位置監視
			this.addEventListener( Event.ENTER_FRAME, enterFrameHandler, false, 0, true )
		}
 
 
 
 
		public function mouseUpHandler(e:MouseEvent):void{
			//監視解除
			this.removeEventListener( Event.ENTER_FRAME, enterFrameHandler );
		}
 
 
 
		public function mouseWheelHandler(e:MouseEvent):void{
			this.camera.orbit( -45, _yaw += e.delta );
		}
 
 
 
		public function enterFrameHandler(e:Event):void{
 
			//ビュー座標???
			var viewNum:Number3D = this.camera.unproject( this.viewport.containerSprite.mouseX, this.viewport.containerSprite.mouseY );
			//ワールド座標?前方投影面の座標???
			var worldNum:Number3D = Number3D.add( viewNum, camera.position );	
 
			var cameraVertex3D:Vertex3D = new Vertex3D( camera.x, camera.y, camera.z );
			var worlsVertex3D:Vertex3D	= new Vertex3D( worldNum.x, worldNum.y, worldNum.z );
 
 			//カメラの座標と投影面の座標を通る直線が無限平面と交差する点???
			var intersectPoint:Vertex3D = plane3d.getIntersectionLine( worlsVertex3D, cameraVertex3D );
 
			//座標に変換
			var n:Number3D = intersectPoint.getPosition();
				n = Number3D.sub( n, subNum );
 
			this.sphere.position = n;
		}
 
 
	}
}

Plane3D(normal:Number3D = null, ptOnPlane:Number3D = null)

package index{
 
 
	import flash.events.Event;
	import org.papervision3d.core.utils.MeshUtil;
	import org.papervision3d.core.math.Plane3D;
	import org.papervision3d.core.math.Number3D;
	import org.papervision3d.events.InteractiveScene3DEvent;
	import org.papervision3d.lights.PointLight3D;
	import org.papervision3d.materials.utils.MaterialsList;
	import org.papervision3d.materials.shadematerials.FlatShadeMaterial;
	import org.papervision3d.objects.DisplayObject3D;
	import org.papervision3d.objects.primitives.Cube;
	import org.papervision3d.view.BasicView;
 
 
 
 
	public class Main extends BasicView{
 
		public function Main(viewportWidth:Number=400, viewportHeight:Number=400, scaleToStage:Boolean=true, interactive:Boolean=true, cameraType:String="TARGET"){
			super(viewportWidth, viewportHeight, scaleToStage, interactive, cameraType);
 
			this.world	= new DisplayObject3D();
			this.scene.addChild( this.world );
 
			this.light	= new PointLight3D();
			this.light.y= -1000;
			this.light.z= -1000;
			this.cube	= new Cube( new MaterialsList( { all:new FlatShadeMaterial( this.light, 0xffffff, 0x00ff00, 50 ) } ) );
			this.cube.material.doubleSided	= true;
 
			this.num	=  new Number3D( 0, 0, 1 );
 
			this.addEventListener( Event.ENTER_FRAME, this.enterFrameHandler, false, 0, true );
			this.startRendering();
		}
 
 
		public var light:PointLight3D
		public var world:DisplayObject3D;
		public var cube:Cube;
		public var num:Number3D;
 
 
 
		public function enterFrameHandler(e:Event):void{
 
			var x:Number = ( this.stage.mouseX - this.stage.stageWidth / 2 ) / ( this.stage.stageWidth / 2 );
			var y:Number = ( this.stage.mouseY - this.stage.stageHeight/ 2 ) / ( this.stage.stageWidth / 2 );
			this.world.rotationY	= x * 180;
			this.world.rotationX	= y * 360;
 
 
			var plane3d:Plane3D	= new Plane3D( this.num, Number3D.ZERO );
			var arr:Array	= MeshUtil.cutTriangleMesh( this.cube, plane3d );
 
			for each( var i:DisplayObject3D in this.world.children ){
				this.world.removeChild( i );
			}
 
			var obj:DisplayObject3D	= arr[0];
			this.world.addChild( obj );
 
			this.num.rotateX( 1 );
		}
 
 
 
 
	}
}

load( "fileName.kmz" )

package shuttle{
 
	import org.papervision3d.objects.parsers.KMZ;
 
	public class Shuttle extends KMZ{
		//EmbedタグでKMZファイルを埋め込み
		[Embed(source="shuttle_nipx.kmz",mimeType="application/octet-stream")]
		private var FileClass:Class;
 
		public function Shuttle(){
			super();
			this.load( new FileClass() );
		}
 
	}
}

var dae = new DAE();
dae.load("Kinkakuji/models/Kinkakuji.dae");

import org.papervision3d.cameras.Camera3D;
import org.papervision3d.scenes.Scene3D;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.materials.ColorMaterial;
import org.papervision3d.render.BasicRenderEngine;
import org.papervision3d.view.Viewport3D;
 
var container:Sprite = new Sprite();
var viewport:Viewport3D = new Viewport3D(200,200);
var renderer:BasicRenderEngine = new BasicRenderEngine();
var scene:Scene3D = new Scene3D();
var camera:Camera3D = new Camera3D();
var material:ColorMaterial = new ColorMaterial();
var plane = new Plane(material,100,100,2,2,null);
 
scene.addChild(plane);
container.addChild(viewport);
addChild(container);
 
renderer.renderScene(scene, camera, viewport);